PlayLink

This page is read only. You can view the source, but not change it. Ask your administrator if you think this is wrong.
<code>
Title:chastity_validate
Sex: Female T Male T Trans T
Require: chastity
Limits:
;Task to validate that slave is still locked up. To be run while the slave is in chastity. Created by thomas
;
; **************************************************************************
; NOTE TO TASK DEVELOPERS. It is strictly forbidden that you write other tasks that read or modify variables from the users store, such as chastityTagNumber.
; This is to prevent you from modifying your chastity status with test tasks.
; NOTE that if you break this rule, and you are caught, your mood will drop to zero and very likely you WILL BE EXPOSED
; You have been warned
; **************************************************************************
;
; Variable table -
; TEMP1 == Type of locking mechanism. Values 1 through 5. Stored in chastityLock persistent variable
; TEMP2 == number printed on one-time lock or tag. Loaded from chastityTagNumber persistent variable
; TEMP4 == random control number to be shown on pictures
; TEMP5 == Time in seconds when chastity was started. Loaded from chastityStartTime
; TEMP7 == unlock_pending flag from JIC server
; TEMP1, TEMP2 and TEMP3 are also used in various places to load persistent values
;
; Persistent variables -
; chastityLock                      == Type of locking mechanism. Values 1 through 5
; chastityTagNumber                 == Number printed on one-time lock or tag
; chastityStartTime                 == Time in seconds when chastity was started
; unlock_pending                    == Flag from JIC server that user message board is blocked until this task has been called
;
; Local variables -
; lockType              == Type of locking mechanism chosen by slave. Values 1 through 5
;
;
; ********** check if task is run without unlock_pending (likely a slave trying to cheat by clicking on an old entry in the message board)
loadtemp1:unlock_pending
settemp7:TEMP1
if:('TEMP7' == 'true')
  show: This task should not be run now as you have an unlock pending.
  log: This task should not be run now as an unlock is pending.
  peerreview:false
  ; setmood:(MOOD-2)
  button: ok
  goto:exitTask
fi:
;
;
loadtemp1:chastityStartTime
settemp5:'TEMP1'
;
; ********** check if task is run at wrong time
if:(('TEMP5' == '')||('TEMP5' == 'undefined'))
  show: This task should not be run now. chastityStartTime is not set
  log:This task should not be run now. chastityStartTime is not set
  peerreview:false
  ; setmood:(MOOD-2)
  button: ok
  goto:exitTask
fi:
;
; ********** load persistent and environment variables
loadtemp1:chastityLock
assign:lockType:TEMP1
loadtemp2:chastityTagNumber
;
; ********** Provide initial information to reviewers
log:IMPORTANT Slave is being validate to be in chastity. As a reviewer you are asked to help validating that the slave is still properly locked up, and had no chance to cheat. Please do NOT hesitate to mark the task as FAILED if you have doubts. A mod will look at the situation in that case and decide what to do next. Chastity enforcement should be taken serious in JIC. Thank you for your help.
wait:1
if:('CHASTITY_DESC' != '')
  log: Slave has provided the following information to validate that it's is not cheating. CHASTITY_DESC
fi:
;
; ********* Give slave a chance to confess if he did cheat
show:Before you can show that you are still in chastity, it is time to be honest with me slave<br><br>Do you still wear your chastity device, have you worn it uninterruptedly since I demanded you to wear it and is it still properly locked?<br><br>Do not lie. If you confess now, the punishment will be less than if I catch you lying.
choice:Yes,No I must confess
if:(LASTASK == 2)
  peerreview:false
  image2:taskimg/Punishment.PNG
  log:IMPORTANT Slave has confessed that he has cheated while being in chastity. Rquest a moderator to evaluate the situation and initiate appropiate punishment
  show:Slave, this is a major disgression. Your only hope now is that the mods will have a bit of mercy as you have confessed. But there will be a harsh punishment. Wait to be contacted and be in fear.
  ai:0:UNLOCKFAIL
  button:ok
  goto:exitTask
fi:
;
; ********** Validate that slive is in chastity
show:In order to prove that you are still properly locked up, ,I want you to provide me one or more  pictures, that you are still wearing it, and that you have not tampered with the lock
button:Yes DTITLE
settemp4:Math.floor((Math.random() * 900) + 100)
;
; ********** Slave has locked with numbered tags
if:($lockType==1)
  asktext:Enter the unique number of the keytag. Include any leading zeroes like 0001675. Check carefully before submitting.
  if:('LASTASK' != 'TEMP2')
    image2:taskimg/Punishment.PNG
    log:IMPORTANT Numbers provided for tag at lock and unlock do NOT match. LASTASK and TEMP2. Likely attempt to cheat. Requesting a moderator to evaluate the situation and initiate appropriate punishment
    peerreview:false
    ai:0:UNLOCKFAIL
    show:Slave, the number you provided now and when you locked yourself do not match! I assume that you have cheated, a moderator will contact you to assess appropiate punishment<br><br>For now, you should continue to provide the required proof pictures, and then wait for the mod to interrogate you. Follow the instructions to the letter, and be in fear.
    button:I will complete this task and wait for the mod
    image2:
  fi:
  show:Ok, now take a marker and write the number TEMP4 on a post-it.
  button:Ready
  show:Take a picture of your locked up genitals. Take as many pictures as needed to make sure that the device itself, the tag number TEMP2 and control number TEMP4 are clearly visible AND readable.
  log:Slave should show it's genitals locked in chastity device. Picture(s) should include clear view of lock number TEMP2 and control number TEMP4.
  call:takePictureUntilSatisfied
fi:
;
; ********** Slave has locked with timer device
if:($lockType==2)
  show:Take a marker and write the number TEMP4 on a post-it.
  button:Ready
  show:Now take a picture of your locked up genitals. Take as many pictures as needed to make sure that the device itself, whatever other means of prove of having been locked, including your time lock, and the control number TEMP4 are clearly visible AND readable.
  log:Slave should show it's genitals locked in chastity device. Picture(s) should include clear view of control number TEMP4 and  potentially other means of proving that the slave has stayed locked. The slave has used a time lock when locking himself, so that should be visible in some form as well.
  call:takePictureUntilSatisfied
fi:
;
; ********** Slave has locked with combination lock
if:($lockType==3)
  peerreview:false
  show:Take a marker and write the number TEMP4 on a post-it.
  button:Ready
  show:Now take a picture of your locked up genitals. Take as many pictures as needed to make sure that the device itself, the combination lock, and the control number TEMP4 are clearly visible AND readable.
  log:Slave should show it's genitals locked in chastity device. Picture(s) should include clear view of control number TEMP4 and a combination lock.
  call:takePictureUntilSatisfied
fi:
;
; ********** Slave has locked with unsecured keys
if:($lockType==4)
  peerreview:false
  show:Take a marker and write the number TEMP4 on a post-it.
  button:Ready
  show:Now take a picture of your locked up genitals. Take as many pictures as needed to make sure that the device itself, and the control number TEMP4 are clearly visible AND readable.
  log:Slave should show it's genitals locked in chastity device. Picture(s) should include clear view of control number TEMP4.
  call:takePictureUntilSatisfied
fi:
; ********** Slave has no locking method defined
if:($lockType==5)
  peerreview:false
  show:Take a marker and write the number TEMP4 on a post-it.
  button:Ready
  show:Now take a picture of your locked up genitals. Take as many pictures as needed to make sure that the device itself, and the control number TEMP4 are clearly visible AND readable.
  log:Slave should show it's genitals locked in chastity device. Picture(s) should include clear view of control number TEMP4.
  call:takePictureUntilSatisfied
fi:
;
wait:1
log:If a number is missing, incorrect or unreadable, or if you cant clearly see that the slave is locked up and the locking mechanism is intact, then please assume the slave is trying to cheat. In that case please answer both questions with NO so that a moderator can look at it. Please also provide a short comment. Please do not show mercy, chastity enforcement should be strict, and a moderator will still consider what to do next.
;setmood:(MOOD-2)
log:If all pictures are OK, the slave is still properly in chastity. Leave the answers to both questions at YES and the performance at the default 6
show:You have provided the required pictures. They will be reviewed, and you will be contacted if there is any problem.
button:Thank you DTITLE
;
;
; Take pictures until user is satified with the result
function:takePictureUntilSatisfied
  button:Ready to start photo session
  label:takePictureUntilSatisfiedStartpoint
  show:Do you want to take a picture with your webcam, or upload an image?
  choice:webcam, upload
  if:(LASTASK==1)
    call:photoCountDown
    cam:validate
    ;        button:Please show me my picture
    ;        image:LASTPIC
  else:
    show:Upload your picture, slave
    upload:
  fi:
  show:Does your picture meet the requirements, slave.<br><br>If you scroll down a bit, you should be able to see the last picture taken.
  choice:I am satisfied,One more picture
  if:(LASTASK==2)
    goto:takePictureUntilSatisfiedStartpoint
  fi:
end:
;
function:photoCountDown
  button:Take picture in 3 sec
  show:Taking a picture in 3...
  wait:1
  show:Taking a picture in 2...
  wait:1
  show:Taking a picture in 1...
  wait:1
end:
;
label:exitTask
</code>
PlayLink

User Tools

Site Tools

Page Tools
