PlayLink

Title:the_maid
Sex: Female T Male T Trans T
Require:
Limits:
;slave is serving as a maid
;
;Standing and serving the Mistress/Master a drink (picture + voice of your designated Mistress/Master)
;Review pictures are taken randomly, chance 50%
;All available decorations have a 50% chance
;Repetition position between 3-6 (actions)
;Standing 60-120 seconds, bowing 15-30 seconds
;
;turn peerreview on
peerreview:true
;
;----------------------- Variables --------------------------
;
;Selected Mistress/Master
if:('DNAME'=='Jennifer')
  assign:domme:'Jennifer'
  assign:typedrink: 'wine'
  assign:item: 'glass'
fi:
if:('DNAME'=='Natasha')
  assign:domme:'Natasha'
  assign:typedrink:'vodka'
  assign:item: 'glass'
fi:
if:('DNAME'=='James')
  assign:domme:'James'
  assign:typedrink: 'beer'
  assign:item:'bottle'
fi:
;
;Spoken voice
assign:Words:'Stand straight slave'
;Preparation Rolls & Cam rolls
assign:PrepRoll:0
;Time in position
assign:PosTime:0
;How many actions
assign:Actions:0
;
;----------------------- Start task --------------------------
;
log:Slave is butler/maid offering drinks. There are 2 basic positions. <br> The slave is either standing straight or bowing. With 1 hand (excepted when wearing handcuffs) holding tray or something similar.<br>
;
image:taskimg/backgrounds/Apartment_2.jpg
image2:taskimg/Default/$domme_Drink.png
;
;Intro
show:Slave, come here. I have an important task for you.
button:Yes DTITLE
show:Your task is to be my $typedrink holder. You will hold my $item and offer it to me whenever I demand it.
button:Yes DTITLE
;
;Preparation
;
;Tray
show:Get a tray slave and place a (filled) $item on it. I want you to hold the tray with one hand.<br>(clumsy slaves may use plastic or other unbreakable items, just hold something!)
button:Yes DTITLE
;
show:Before we start, get naked slave.
button:Naked
show:Just naked is boring to look at slave, let's enhance your appearance a bit.
button:Yes DTITLE
;
;Chastity
if:(INCHASTITY)
  log:Slave is in chastity
else:
  call:PrepRoll
  if:(L_CHASTITY> 2 && PrepRoll > 50)
    image2:taskimg/Default/$domme_Chastity.png
    log:Slave is in chastity.
    show:You will look more appealing wearing a chastity cage. So put on your cage.
    button:Caged
    image2:taskimg/Default/$domme_Drink.png
  fi:
fi:
;
;Nipple clamps
call:PrepRoll
if:(T_NIPPLECLAMPS && PrepRoll > 50)
  log:Slave wears nippleclamps.
  show:Present your nipples for me; I want to see you wearing nipple clamps.
  button:Nipple clamps on
fi:
;
;Sissy
call:PrepRoll
if:(L_SISSY >3 && PrepRoll > 50)
  log:Slave is wearing something sissy. (garter belt, bra, stockings, ...)
  show:Let's enhance your submission by wearing something sissy. (garter belt, bra, stockings, ...)
  button:Dressed sissy
fi:
;
;Gag
call:PrepRoll
if:(T_GAG && PrepRoll > 50)
  log:Slave is wearing a gag.
  show:I want you to be silent before me slave. Put on your gag.
  button:Gagged
fi:
;
;Handcuffs
call:PrepRoll
if:(T_HANDCUFFS && PrepRoll > 50)
  image2:taskimg/Default/$domme_Handcuffs.png
  log:IMPORTANT Slave is wearing handcuffs. Slave will be holding the tray with both hands.
  show:I think it's best that you carry the tray with both hands. Put on your handcuffs.
  button:Wearing handcuffs
  image2:taskimg/Default/$domme_Drink.png
fi:
;
;Explaining positions
show:Slave there are only 2 positions you must know. <br>Standing completely still besides me and offering me a drink.
button:I understand
show:When you hear me say
wait:2
call:Speak
image2:taskimg/tasks/maid/maid_stand.png
show:Then you stand up straight before me holding the tray.
button:Understood
show:When you hear me say
wait:2
assign:Words:'My drink slave'
call:Speak
image2:taskimg/tasks/maid/maid_bow.png
show:Then you bow forward and wait until I tell you to straighten up again.
button:Understood
image2:taskimg/tasks/maid/maid_stand.png
;
;Book
call:PrepRoll
if:(PrepRoll > 50)
  show:I want you to stand absolutely still before me. An effective method to keep you still is with a book on your head. Do you believe you can perform the positions balancing a book on your head or are you to clumsy? <br> Refusing will have consequences of course!
  choice:I can DTITLE, To clumsy DTITLE
  if:(LASTASK == 1)
    log:Slave will have a book (or something similar) on is head. Extra credit for the slave!
    show:Very good slave. Just make sure it doesn't drop.
    button:I will try DTITLE
  fi:
  if:(LASTASK == 2)
    log:Slave refuses to have a book (or something similar) on is head. Be more harsh reviewing.
    show:I will look extra carefully at your performance slave.
    button:Sorry DTITLE
  fi:
fi:
;
;Face mask allowed
if:(L_FACE < 2)
  show:You are allowed to wear a mask slave.
  button:Ok DTITLE
fi:
;
;Ready for first position
show:Ready to start? Stand straight slave.
button:Ready DTITLE (10 seconds)
assign:Words:'Stand straight slave'
call:Speak
show:Stand straight slave.
log:Task starts and slave is standing straight in picture below with items described above.
wait:30
cam:temp
wait:30
;
;Actual task. Each action is always a set of 2 positions.
;How many repetitions (actions 3-6)
assign:Actions:Math.floor((Math.random() * 3) + 3)
while:(Actions > 0)
  ;Slave ordered to bow
  call:Bowing
  ;Slave ordered to stand
  call:Standing
  assign:Actions: $Actions -1
endwhile:
;
;End of the task
sound:bell.wav
image2:taskimg/Default/$domme_Drunk.png
show:I think I have had enough $typedrink for today slave. Just one more thing before you go. <br>Did you serve me correctly slave?
choice:I did DTITLE, I failed DTITLE
;Ask if the slave served as expected and ending task
if:(LASTASK == 1)
  image2:taskimg/Default/$domme_Happy.png
  log:Slave declares to have served correctly.
  show:I'm pleased to hear that. You may leave now.
fi:
if:(LASTASK == 2)
  image2:taskimg/Default/$domme_Angry.png
  log:Slave admits not serving correctly, please give a low rating or even mark the task as failed!
  show:You did not serve me correctly! You wil be punished for your errors. <br>Leave now.
fi:
;
button:Bye DTITLE
;
;------------------------ End task --------------------------
;
;----------------------- Functions --------------------------
;
function:Standing
  ;Slave is standing
  assign:logText: 'Slave is standing in picture below.'
  assign:Words:'Stand straight slave'
  ;
  call:Speak
  show:Stand straight slave.
  image2:taskimg/tasks/maid/maid_stand.png
  ;Start time standing position
  wait:60
  ;Review picture
  call:PrepRoll
  if:(PrepRoll > 50)
    log:$logText
    wait:5
    cam:temp
  fi:
  ;Extra stand time
  assign:PosTime:Math.floor((Math.random() * 60) + 1)
  wait:PosTime
end:
;
;--------------------------------------------------
;
function:Bowing
  ;Slave is bowing
  assign:logText: 'Slave is bowing in picture below.'
  assign:Words:'My drink slave'
  ;
  call:Speak
  show:My drink slave.
  image2:taskimg/tasks/maid/maid_bow.png
  ;Start time bow position
  wait:15
  ;Review picture
  call:PrepRoll
  if:(PrepRoll > 50)
    log:$logText
    wait:5
    cam:temp
  fi:
  ;Extra bow time
  assign:PosTime:Math.floor((Math.random() * 15) + 1)
  wait:PosTime
end:
;
;---------------------------------------------
;
function:PrepRoll
  ;Different rolls for decoration and pictures.
  assign:PrepRoll:Math.floor((Math.random() * 100) + 1)
end:
;
;-------------------------------------------------
;
function:Speak
  ;The voice of the different Master/Mistress
  if:('DNAME'=='Natasha')
    speaknat:$Words
  else:
    if:('DNAME'=='James')
      speakjames:$Words
    else:
      speakjen:$Words
    fi:
  fi:
end:
;
;----------------------- End Functions ---------------------
;
;
;